switch.S 2.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107
  1. /*
  2. * Context-switch PIT IRQ stub.
  3. *
  4. * On entry the CPU has already pushed EFLAGS, CS, EIP onto the
  5. * current process's stack. We save the rest, bump the tick counter,
  6. * and -- when the timeslice expires -- call schedule() and swap ESP
  7. * to the next process.
  8. *
  9. * Shadow buffer flush: damage-driven, done by the main loop (byte budget).
  10. * Main loop checks dirty rows and copies only what changed.
  11. *
  12. * Serial poll: every tick, check UART for received data and push
  13. * to ring buffer so no bytes are lost during preemption.
  14. */
  15. .code32
  16. .text
  17. .extern ticks
  18. .extern current_pid
  19. .extern procs
  20. .extern schedule
  21. .extern serial_poll
  22. .extern kdbg_pit_tick
  23. .extern tss
  24. .include "irqret.inc"
  25. /* struct process offsets (must match process.h / process.c) */
  26. .equ PCB_ESP, 0
  27. .equ PCB_CR3, 32
  28. .equ PCB_KSTACK_TOP, 36
  29. .equ PCB_CPU_TICKS, 108 /* after cwd[64] */
  30. .equ PCB_SIZE, 116 /* sizeof(struct process): 44 + cwd[64] + 2*4 */
  31. .equ TIMESLICE, 20
  32. .globl pit_irq_stub
  33. pit_irq_stub:
  34. pusha
  35. /* Load the kernel data segment. The PIT can fire while a ring-3 process
  36. * is running, and in that case the CPU has switched CS/SS but left DS
  37. * null (IRET reset it when it returned to ring-3); the data accesses
  38. * below (ticks, counters, procs, tss) go through DS and would #GP. */
  39. movw $0x10, %ax
  40. movw %ax, %ds
  41. movw %ax, %es
  42. movw %ax, %fs
  43. movw %ax, %gs
  44. /* ticks++ and send EOI -- always, even when we don't switch. */
  45. incl ticks
  46. movb $0x20, %al
  47. outb %al, $0x20
  48. /* Account this tick to the process that was interrupted (for `top`). */
  49. movl current_pid, %eax
  50. imull $PCB_SIZE, %eax
  51. addl procs, %eax
  52. incl PCB_CPU_TICKS(%eax)
  53. /* Poll UART for received serial data (prevents FIFO overflow). */
  54. call serial_poll
  55. /* On-screen debug heartbeat / status refresh (no serial console on
  56. * some targets; this keeps a live indicator on the framebuffer). */
  57. call kdbg_pit_tick
  58. /* Decrement timeslice counter; switch only when it reaches 0. */
  59. decl slice_counter
  60. jnz .no_switch
  61. /* Reset counter for next timeslice. */
  62. movl $TIMESLICE, slice_counter
  63. /* Save current ESP into procs[current_pid].esp (procs is a pointer). */
  64. movl current_pid, %eax
  65. imull $PCB_SIZE, %eax
  66. addl procs, %eax
  67. movl %esp, PCB_ESP(%eax)
  68. /* Let the C scheduler pick the next process. */
  69. call schedule
  70. /* Load new ESP, CR3, and TSS esp0 from procs[current_pid]. */
  71. movl current_pid, %eax
  72. imull $PCB_SIZE, %eax
  73. addl procs, %eax
  74. movl PCB_ESP(%eax), %esp
  75. movl PCB_CR3(%eax), %ebx
  76. movl %ebx, %cr3
  77. movl PCB_KSTACK_TOP(%eax), %ebx
  78. movl %ebx, tss+4 /* TSS.esp0 = this process's ring-0 stack top */
  79. .no_switch:
  80. /* Both paths (return to the interrupted process, or to one just switched
  81. * in) must leave a usable data segment selector for the context being
  82. * resumed; ring-3 needs 0x23 (see irqret.inc). */
  83. IRQ_RETURN_DS 36
  84. popa
  85. iret
  86. .data
  87. .align 4
  88. slice_counter:
  89. .long TIMESLICE