kexec_tramp.S 1.6 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859
  1. /* Position-independent kexec trampoline. Copied to 0x800 at runtime (see
  2. * kexec.c) because the final copy overwrites the kernel code we're executing.
  3. *
  4. * Args in registers (set by kexec.c):
  5. * eax = source (staging buffer)
  6. * ebx = dest (0x7E00)
  7. * ecx = byte count
  8. * edx = entry (new kernel_main)
  9. *
  10. * Also rebuilds a flat GDT at 0x900 and loads it, so the new kernel's segment
  11. * reloads (iret on the first context switch) don't read the old GDT that lives
  12. * inside the kernel region we overwrite. 0x900 is below 0x7E00 and is never
  13. * overwritten, so the GDT survives. Clobbers esi/edi. Never returns.
  14. */
  15. .code32
  16. .text
  17. .globl kexec_trampoline
  18. kexec_trampoline:
  19. cli
  20. pushl %eax
  21. pushl %ebx
  22. pushl %ecx
  23. pushl %edx
  24. /* Mask all IRQs. */
  25. movb $0xFF, %al
  26. outb %al, $0x21
  27. outb %al, $0xA1
  28. /* Build flat GDT (base 0 / 4 GB) at 0x900 and load it. */
  29. movl $0x900, %edi
  30. movl $0, 0(%edi) /* null */
  31. movl $0, 4(%edi)
  32. movl $0x0000FFFF, 8(%edi) /* code: limit 0xFFFF, base low 0 */
  33. movl $0x00CF9A00, 12(%edi)/* code: base mid 0, 0x9A, 0xCF, base hi 0 */
  34. movl $0x0000FFFF, 16(%edi)/* data: limit 0xFFFF, base low 0 */
  35. movl $0x00CF9200, 20(%edi)/* data: base mid 0, 0x92, 0xCF, base hi 0 */
  36. movw $0x17, 24(%edi) /* gdtr limit = 23 */
  37. movl $0x900, 26(%edi) /* gdtr base = 0x900 */
  38. lgdt 24(%edi)
  39. popl %edx
  40. popl %ecx
  41. popl %ebx
  42. popl %eax
  43. /* Copy new kernel: src=eax -> dst=ebx, count=ecx. */
  44. movl %eax, %esi
  45. movl %ebx, %edi
  46. cld
  47. rep movsb
  48. movl $0x20800, %esp
  49. jmp *%edx
  50. .globl kexec_trampoline_end
  51. kexec_trampoline_end:
  52. nop