switch.S 2.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104
  1. /*
  2. * Context-switch PIT IRQ stub.
  3. *
  4. * On entry the CPU has already pushed EFLAGS, CS, EIP onto the
  5. * current process's stack. We save the rest, bump the tick counter,
  6. * and -- when the timeslice expires -- call schedule() and swap ESP
  7. * to the next process.
  8. *
  9. * Shadow buffer flush: every ~33 ticks (30Hz), set pending flag.
  10. * Main loop checks dirty rows and copies only what changed.
  11. *
  12. * Serial poll: every tick, check UART for received data and push
  13. * to ring buffer so no bytes are lost during preemption.
  14. */
  15. .code32
  16. .text
  17. .extern ticks
  18. .extern current_pid
  19. .extern procs
  20. .extern schedule
  21. .extern vga_shadow_flush_pending
  22. .extern serial_poll
  23. .extern kdbg_pit_tick
  24. .extern tss
  25. /* struct process offsets (must match process.h / process.c) */
  26. .equ PCB_ESP, 0
  27. .equ PCB_CR3, 32
  28. .equ PCB_KSTACK_TOP, 36
  29. .equ PCB_SIZE, 44 /* sizeof(struct process): 4+4+4+12+4+4+4+4+4 = 44 */
  30. .equ TIMESLICE, 20
  31. .equ FLUSH_INTERVAL, 33 /* 1000Hz PIT / 30Hz flush ≈ 33 ticks */
  32. .globl pit_irq_stub
  33. pit_irq_stub:
  34. pusha
  35. /* Load the kernel data segment. The PIT can fire while a ring-3 process
  36. * is running, and in that case the CPU has switched CS/SS but left DS
  37. * null (IRET reset it when it returned to ring-3); the data accesses
  38. * below (ticks, counters, procs, tss) go through DS and would #GP. */
  39. movw $0x10, %ax
  40. movw %ax, %ds
  41. movw %ax, %es
  42. movw %ax, %fs
  43. movw %ax, %gs
  44. /* ticks++ and send EOI -- always, even when we don't switch. */
  45. incl ticks
  46. movb $0x20, %al
  47. outb %al, $0x20
  48. /* Poll UART for received serial data (prevents FIFO overflow). */
  49. call serial_poll
  50. /* On-screen debug heartbeat / status refresh (no serial console on
  51. * some targets; this keeps a live indicator on the framebuffer). */
  52. call kdbg_pit_tick
  53. /* Shadow buffer flush at 30Hz: set pending flag, main loop does the copy. */
  54. decl flush_counter
  55. jnz .no_flush
  56. movl $FLUSH_INTERVAL, flush_counter
  57. movl $1, vga_shadow_flush_pending
  58. .no_flush:
  59. /* Decrement timeslice counter; switch only when it reaches 0. */
  60. decl slice_counter
  61. jnz .no_switch
  62. /* Reset counter for next timeslice. */
  63. movl $TIMESLICE, slice_counter
  64. /* Save current ESP into procs[current_pid].esp (procs is a pointer). */
  65. movl current_pid, %eax
  66. imull $PCB_SIZE, %eax
  67. addl procs, %eax
  68. movl %esp, PCB_ESP(%eax)
  69. /* Let the C scheduler pick the next process. */
  70. call schedule
  71. /* Load new ESP, CR3, and TSS esp0 from procs[current_pid]. */
  72. movl current_pid, %eax
  73. imull $PCB_SIZE, %eax
  74. addl procs, %eax
  75. movl PCB_ESP(%eax), %esp
  76. movl PCB_CR3(%eax), %ebx
  77. movl %ebx, %cr3
  78. movl PCB_KSTACK_TOP(%eax), %ebx
  79. movl %ebx, tss+4 /* TSS.esp0 = this process's ring-0 stack top */
  80. .no_switch:
  81. popa
  82. iret
  83. .data
  84. .align 4
  85. slice_counter:
  86. .long TIMESLICE
  87. flush_counter:
  88. .long FLUSH_INTERVAL